Informationen zu Spielorten

zurück zur Übersicht der Abfragen: zurück

Bilder der Theatergebäude

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX mmd: <https://mtm.uni-trier.de/entity/> 
PREFIX mmdt: <https://mtm.uni-trier.de/prop/direct/>

#defaultView:ImageGrid
SELECT ?gebäudeLabel ?bild WHERE {
    ?gebäude mmdt:P3 mmd:Q239.  #Gebäude ist ein Theatergebäude
    ?gebäude mmdt:P2 ?WikiDataEntity. #Gebäude hat ein exact match mit einem Wikidata-Item
  
    SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P18 ?bild.  # Wikidata-Item hat über P18 ein Bild
    }
  
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen gab es in Berlin?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?spielortLabel ?inszenierung ?inszenierungLabel WHERE {   
   ?inszenierung wdt:P3 wd:Q309.   # Inszenierung ist eine Inszenierung (Q309)
   ?inszenierung wdt:P8 ?spielort. # Inszenierung hat einen Spielort (bspw. ein Theater) (P8)
   ?spielort wdt:P21 wd:Q237.      # der Spielort befindet sich in einem Ort – in dem Fall Berlin (Q237)
   SERVICE wikibase:label {        # Fügt lesbare Labels hinzu
   bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
 }
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen fanden in Theatergebäuden statt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?spielortLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.   #Inszenierung ist eine Inszenierung [Q309]  
  ?inszenierung wdt:P8 ?spielort. #Inszenierung hat einen Spielort (bspw. ein Theater) [P8]
  ?spielort wdt:P3 wd:Q239.       #Spielort ist ein [P3] Theater/Theatergebäude [Q239]
  SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen fanden nicht in Theatergebäuden statt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?spielortLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.   #Inszenierung ist eine Inszenierung [Q309]  
  ?inszenierung wdt:P8 ?spielort. #Inszenierung hat einen Spielort [P8]
  MINUS {
    ?spielort wdt:P3 wd:Q239.     #MINUS die Inszenierungen, die in einem Theatergebäude stattfanden
  }
  SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
     bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen fanden in Gerichtsgebäuden statt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?spielortLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.   #Inszenierung ist eine Inszenierung [Q309]  
  ?inszenierung wdt:P8 ?spielort. #Inszenierung hat einen Spielort (bspw. ein Theater) [P8]
  ?spielort wdt:P3 wd:Q240.       #Spielort ist ein [P3] Gericht [Q240]
  SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen