Bühnenkonzeptionen

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Liste aller Beschreibungen von Bühnenkonzeptionen

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?buehnenbeschreibung WHERE {
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P35 ?buehnengestaltung.         #Inszenierung hat eine Bühnengestaltung [P35]
    ?buehnengestaltung wdt:P54 ?buehnenbeschreibung.  #Bühnengestaltung hat eine Beschreibung [P54] 
        SERVICE wikibase:label {                      #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}

Klicke hier: SPARQL-Abfrage testen

Woraus bestehen die Bühnenkonzeptionen (aus welchen Bestandteilen)?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>


SELECT ?inszenierungLabel ?anzahl ?farbeLabel ?bestandteilLabel  WHERE {
  ?inszenierung wdt:P3 wd:Q309.
  ?inszenierung wdt:P35 ?buehnengestaltung. #Inszenierung hat Bühnengestaltung
  
  ?buehnengestaltung p:P50 ?statement.  #Statement für die Bestandteile, die mit Qualifikatoren versehen sind
  ?statement ps:P50 ?bestandteil.       #Statement besteht aus Bestandteil
  ?statement pq:P49 ?farbe.             #Bestandteil hat Farbe
  ?statement pq:P57 ?anzahl.            #Anzahl des Bestandteils

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".
  }
}

ORDER BY ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen haben mit multimedialen Elementen gearbeitet und was waren diese Elemente?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?multielementeLabel ?beschreibung WHERE {
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P35 ?buehnengestaltung.       #Inszenierung hat eine Bühnengestaltung [P35]
    ?buehnengestaltung wdt:P82 ?multielemente.      #Bühnengestaltung hat multimediale Elemente [P82]
    ?buehnengestaltung wdt:P54 ?beschreibung        #Bühnengestaltung hat eine Beschreibung [P54] (Multimediale Elemente auch beschrieben)
        SERVICE wikibase:label {                    #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}

Klicke hier: SPARQL-Abfrage testen