Gender-related questions

Back to the overview of all query topics: back

Bar chart showing the number of female, male and non-binary real persons involved in a production

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

#defaultView:BarChart
SELECT ?genderLabel (COUNT(?person) AS ?count) WHERE {
  ?person wdt:P3 wd:Q241.                        # Person is a real person
  ?person wdt:P17 ?gender.                       # Person has a gender
  ?production ?function ?person.                 # Production is connected to the person via a function
  ?production wdt:P3 wd:Q309.                    # Production is a theatre production

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".      # Adds readable labels
  }
}
GROUP BY ?genderLabel
ORDER BY ?genderLabel

Click here: Test SPARQL query

Directors and their gender

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?production ?productionLabel ?directorLabel ?genderLabel WHERE {
    ?production wdt:P3 wd:Q309.             # Production
    ?production wdt:P15 ?director.          # Production has a director
    ?director wdt:P17 ?gender.              # Director has a gender

    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en".
    }
}

Click here: Test SPARQL query

Which productions were directed by male/female/non-binary directors?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?production ?productionLabel ?directorLabel WHERE {
    ?production wdt:P3 wd:Q309.
    ?production wdt:P15 ?director.     # Production has a director
    ?director wdt:P17 wd:Q9.           # Gender: male (Q9)

    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en".
    }
}

In line 6: Leave wd:Q9 for male directors, insert wd:Q10 for female directors, or insert wd:Q11 for non-binary directors.

Click here: Test SPARQL query

Which productions cast/did not cast the roles as specified in the literary source material with regard to gender? Which roles are involved?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?production ?productionLabel ?roleLabel ?roleGenderLabel ?characterLabel ?characterGenderLabel WHERE {
  ?production wdt:P3 wd:Q309.
  ?production wdt:P25 ?role.              # Production has roles
  ?role wdt:P17 ?roleGender.              # Role gender
  ?role wdt:P87 ?character.               # Role based on literary character
  ?character wdt:P17 ?characterGender.    # Literary character gender

  FILTER (?roleGender != ?characterGender)

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}
ORDER BY ?production

In line 10: To display which roles match the gender of the character from the literary source, remove the exclamation mark: (?genderRole = ?genderCharacter). To display which roles from the production and characters from the literary source have different genders: (?genderRole != ?genderCharacter).

Click here: Test SPARQL query

In which productions was character X (any character) cast as female/male/non-binary?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?production ?productionLabel ?role ?roleLabel WHERE {
  ?production wdt:P25 ?role.
  ?role wdt:P87 wd:Q45.       # Based on character Chairman
  ?role wdt:P17 wd:Q10.       # Gender: female

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}

In line 7: wd:Q10 for female cast, wd:Q9 for male cast, wd:Q11 for non-binary cast

In line 6: To change the character on which the role is based:

• wd:Q45 for the character of the Presiding Judge
• wd:Q27 for the defendant
• wd:Q30 for the court reporter
• wd:Q31 for Lauterbach
• wd:Q35 for Meiser
• wd:Q38 for the defence counsel
• wd:Q42 for the prosecutor
• wd:Q47 for the court officer

Click here: Test SPARQL query