Costumes

Back to the overview of all query topics: back

Description of all costumes for all roles

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?productionLabel ?roleLabel ?costumeLabel ?description WHERE {
  ?costume wdt:P3 wd:Q312.          # Costume
  ?costume wdt:P54 ?description.

  ?costume p:P81 ?statement.
  ?statement ps:P81 ?role.
  ?statement pq:P32 ?production.

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}
ORDER BY ?productionLabel

Click here: Test SPARQL query

What parts make up the individual costumes?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?productionLabel ?roleLabel ?componentLabel ?colorLabel WHERE {
  ?role wdt:P55 ?costume.

  ?costume p:P50 ?statement.
  ?statement ps:P50 ?component.
  ?statement pq:P49 ?color.

  ?costume p:P81 ?stmt2.
  ?stmt2 ps:P81 ?role.
  ?stmt2 pq:P32 ?production.

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}
ORDER BY ?productionLabel

Click here: Test SPARQL query

Descriptions of all costumes for roles based on a specific literary character

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?productionLabel ?costumeLabel ?description WHERE {
  wd:Q27 wdt:P88 ?role.        # Character: Accused
  ?role wdt:P55 ?costume.
  ?costume wdt:P54 ?description.

  ?costume p:P81 ?statement.
  ?statement ps:P81 ?role.
  ?statement pq:P32 ?production.

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}
ORDER BY ?productionLabel

In line 5: wd:Q27 for the roles based on the character of the defendant. To output the costumes of other roles, the character of the literary basis on which they are based must be changed:

• wd:Q27 for defendant
• wd:Q30 for court reporter
• wd:Q31 for Lauterbach
• wd:Q35 for Meiser
• wd:Q38 for defense counsel
• wd:Q42 for prosecutor
• wd:Q45 for presiding judge
• wd:Q47 for court officer

Click here: Test SPARQL query

Are there any productions inwhich the defendant does not wear a uniform? If so, which ones?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?production ?productionLabel ?symbolism WHERE {
  wd:Q27 wdt:P88 ?role.

  ?role p:P55 ?statement.
  ?statement ps:P55 ?costume.
  ?statement pq:P32 ?production.

  ?costume wdt:P56 ?symbolism.
  FILTER (?symbolism != wd:Q111)  # Exclude uniform

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
  }
}

Click here: Test SPARQL query