Gender-bezogene Fragen

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Bar chart der Anzahl von weiblichen, männlichen und non-binären realen Personen, die in einer Inszenierung involviert sind

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

#defaultView:BarChart
SELECT ?genderLabel (COUNT (?person) AS ?count) WHERE {
  ?person wdt:P3 wd:Q241. #Person ist eine reale Person
  ?person wdt:P17 ?gender. #Person hat Gender
  ?inszenierung ?funktion ?person. #Inszenierung ist über eine Funktion mit der Person verknüpft.
  ?inszenierung wdt:P3 wd:Q309. #Inszenierung ist eine Inszenierung
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

GROUP BY ?genderLabel
ORDER BY ?genderLabel

Klicke hier: SPARQL-Abfrage testen

Regisseur:innen und ihr Gender

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?theaterregisseurInLabel ?genderLabel WHERE {
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P15 ?theaterregisseurIn.  #Inszenierung hat ein:e Regisseur:in [P15]
    ?theaterregisseurIn wdt:P17 ?gender.        #Regisseur:in hat ein Gender [P17]
    SERVICE wikibase:label {                    #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen wurden von männlichen/weiblichen/non-binären Regisseur:innen betreut?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?theaterregisseurInLabel WHERE {
    ?inszenierung wdt:P3 wd:Q309.   
    ?inszenierung wdt:P15 ?theaterregisseurIn.  #Inszenierung hat ein:e Regisseur:in (P15)
    ?theaterregisseurIn wdt:P17 wd:Q9.          #Regisseur:ins Gender (P17) ist männlich (Q9) / für weiblich (Q10) / für non-binär (Q11)
    SERVICE wikibase:label {                    #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}

In Zeile 6: für männliche Regisseure wd:Q9. stehen lassen, für weibliche Regisseurinnen wd:Q10. an dieser Stelle einfügen oder für nicht-binäre Regisseur:innen wd:Q11. an dieser Stelle einfügen.

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen hat die Rollen so besetzt/nicht so besetzt, wie es in der literarischen Vorlage bzgl. Gender vorgegeben ist? Um welche Rollen handelt es sich?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?rollenLabel ?genderRolleLabel ?litFigurLabel ?genderFigurLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.
  ?inszenierung wdt:P25 ?rollen.         #Inszenierung hat Rollen (P25)
  ?rollen wdt:P17 ?genderRolle.          #Rolle hat ein Gender (P17)
  ?rollen wdt:P87 ?litFigur.             
#Rolle basiert auf literarischer Figur (P87)
  ?litFigur wdt:P17 ?genderFigur.        
#Literarische Figur hat ein Gender (P17)

  FILTER (?genderRolle != ?genderFigur)  
#Gender der Rolle stimmt (nicht „!=”) mit Gender der Figur überein. Wenn sie übereinstimmen sollen ohne Ausrufezeichen vor dem Gleichzei-chen.

      SERVICE wikibase:label {           #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}
ORDER BY ?inszenierung      #sortiert die Ergebnisse nach Inszenierun-gen

In Zeile 10: Um ausgeben zu lassen, welche Rollen mit dem Gender der Figur aus der literarischen Grundlage übereinstimmen, Ausrufezeichen entfernen: (?genderRolle = ?genderFigur). Um ausgeben zu lassen, bei welchen Rollen aus der Inszenierung und Figuren aus der literarischen Grundlage sich die Gender unterscheiden: (?genderRolle != ?genderFigur).

Klicke hier: SPARQL-Abfrage testen

Bei welchen Inszenierungen war die Figur X (beliebige Figur) als Rolle weiblich/männlich/non-binär besetzt?

#bei welchen Inszenierungen war die Figur des Vorsitzenden als Rolle weiblich besetzt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?rolle ?rolleLabel WHERE {
  ?inszenierung wdt:P25 ?rolle.       #Inszenierung hat Rollen [P25]
  ?rolle wdt:P87 wd:Q45.              #Rolle basiert auf der literarischen Figur [P87] des Vorsitzenden (Figur) [Q45]
  ?rolle wdt:P17 wd:Q10.              #Gender [P17] der Rolle ist weiblich [Q10] (für männlich [Q9], für non-binär [Q11])

  SERVICE wikibase:label {            #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
}
}

In Zeile 7: wd:Q10 für weibliche Besetzung, wd:Q9 für männliche Besetzung, wd:Q11 für non-binäre Besetzung

In Zeile 6: Um die Figur, auf der die Rolle basiert, zu ändern:

• wd:Q45 für Figur des Vorsitzenden
• wd:Q27 für Angeklagter
• wd:Q30 für Protokollführerin
• wd:Q31 für Lauterbach
• wd:Q35 für Meiser
• wd:Q38 für Verteidiger
• wd:Q42 für Staatsanwältin
• wd:Q47 für Wachtmeister

Klicke hier: SPARQL-Abfrage testen