Personen

zurück zur Übersicht der Abfragen: zurück

Liste aller Personen mit ihrem Gender und ihrer Funktion innerhalb der Inszenierung

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT  ?inszenierungLabel ?personLabel ?vornameLabel ?nachnameLabel ?genderLabel ?funktionLabel WHERE {
  ?person wdt:P3 wd:Q241. #Person ist eine reale Person
  OPTIONAL { #Falls in einem Personen-Item diese Informationen fehlen
  ?person wdt:P17 ?gender. #Person hat Gender
  ?person wdt:P27 ?vorname. #Person hat Vorname
  ?person wdt:P28 ?nachname. } #Person hat Nachname
  ?inszenierung ?funktion ?person. #Inszenierung ist über eine Funktion mit der Person verknüpft.
  ?inszenierung wdt:P3 wd:Q309. #Inszenierung ist eine Inszenierung
  
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

ORDER BY ?inszenierung

Gibt es eine Regieperson, die mehrere Inszenierungen betreut hat? Wenn ja, welche waren es?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?regie ?regieLabel ?inszenierung ?inszenierungLabel WHERE {
  
  {
    SELECT ?regie (COUNT(?inszenierung) AS ?anzahlInszenierungen) WHERE { #Query von Frage davor als Subquery für Anzahl der Inszenierungen
      ?inszenierung wdt:P15 ?regie.
      ?regie wdt:P18 ?gnd.
    }
    GROUP BY ?regie ?gnd
    HAVING (COUNT(?inszenierung) > 1)
  }
  
  ?inszenierung wdt:P15 ?regie.          #Hauptquery, um Inszenieurng der Regieperson im Ergebnis mit ausgeben zu können

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}
ORDER BY ?regieLabel ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen

Gibt es eine:n Darsteller:in, der oder die bei mehreren Inszenierungen mitspielte? Wenn ja, welche waren es?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?darstellerIn ?darstellerInLabel ?inszenierung ?inszenierungLabel WHERE {
{
SELECT ?darstellerIn ?darstellerInLabel (COUNT(?inszenierung) AS ?count) WHERE { #Query von Frage davor als Subquery für Anzahl der Inszenierungen
  ?inszenierung wdt:P14 ?darstellerIn.                                           #Inszenierung hat ein:e Schauspieler:in 
#nicht jede Schauspieler:in hat eine GND Nummer
}
GROUP BY ?darstellerIn ?darstellerInLabel
HAVING (COUNT(?inszenierung) > 1)
}
?inszenierung wdt:P14 ?darstellerIn.                                              #Hauptquery, um Inszenieurng der Schauspieler:in im Ergebnis mit ausgeben zu können

  SERVICE wikibase:label {                                                        #Labels für lesbare Namen
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

ORDER BY ?darstellerInLabel ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen