Zur Übersicht dieser Wikibase

Zurück zur Übersicht aller Abfragethemen: zurück

Liste aller Properties

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?theaterregisseurIn ?theaterregisseurInLabel ?gender ?genderLabel WHERE {
    ?inszenierung wdt:P15 ?theaterregisseurIn.  #Inszenierung hat ein:e Regisseur:in [P15]
    ?theaterregisseurIn wdt:P17 ?gender.        #Regisseur:in hat ein Gender [P17]
    SERVICE wikibase:label {                    #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
}
}

Welche Inszenierungen sind auf dieser Wikibase angelegt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.
   SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
   bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
  }
}

Karte aller Inszenierungsorte

PREFIX wd: <http://www.wikidata.org/entity/> #wikidata wd
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata wdt

PREFIX mmd: <https://mtm.uni-trier.de/entity/> #mtm mmd
PREFIX mmdt: <https://mtm.uni-trier.de/prop/direct/> #mtm mmdt
#defaultView:Map
SELECT ?item ?itemLabel ?locLabel ?WikiDataEntity ?coordinateLocation WHERE {
  # Abfrage auf meiner Wikibase
  ?item mmdt:P8 ?loc.
  ?loc mmdt:P2 ?o.  # P2 = exakte Übereinstimmung Wikidata-item
  
  # Wikidata-Abfrage
  BIND(IRI(REPLACE(STR(?o), "https://www.wikidata.org/wiki", "http://www.wikidata.org/entity", "i")) as ?WikiDataEntity).
SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P625 ?coordinateLocation  # P625 = Koordinaten in Wikidata
  }
  
  # Label-Service für lokale Wikibase
  SERVICE wikibase:label {     bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".   }
}