Zur Übersicht dieser Wikibase

Zurück zur Übersicht aller Abfragethemen: zurück

Liste aller Properties

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?property ?propertyLabel
WHERE {
  ?property a wikibase:Property .
 
    SERVICE wikibase:label {                         #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
    }
}
ORDER BY ASC(xsd:integer(STRAFTER(STR(?property), 'P')))

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen sind auf dieser Wikibase angelegt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel WHERE {
  ?inszenierung wdt:P3 wd:Q309.    #Inszenierung ist ein(e) (P3) Inszenierung (Q309)
   SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
   bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen

Karte aller Inszenierungsorte

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

PREFIX mmd: <https://mtm.uni-trier.de/entity/> 
PREFIX mmdt: <https://mtm.uni-trier.de/prop/direct/>

#defaultView:Map
SELECT ?inszenierung ?inszenierungLabel ?spielortLabel ?WikiDataEntity ?koordinaten WHERE {

  ?inszenierung mmdt:P3 mmd:Q309.   #Inszenierung ist eine Inszenierung (Q309).  
  ?inszenierung mmdt:P8 ?spielort.
  ?spielort mmdt:P2 ?WikiDataEntity.  # P2 = exakte Übereinstimmung Wikidata-item
  
SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P625 ?koordinaten  # P625 = Koordinaten in Wikidata
  }
  SERVICE wikibase:label {     
  bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".   
  }
}

Klicke hier: SPARQL-Abfrage testen

Welche und wie viele Personen sind auf dieser Wikibase angelegt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>


SELECT ?person ?personLabel WHERE {
  ?person wdt:P3 wd:Q241.  # Person ist ein(e) (P3) reale Person (Q241)
  SERVICE wikibase:label {     bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".   
  }
}

Die Anzahl der Ergebnisse entspricht der Anzahl an realen Personen, die auf der Wikibase angelegt sind.

Klicke hier: SPARQL-Abfrage testen

Falls diese Anzahl jedoch als Ergebnis ausgegeben werden soll, kann folgende Anfrage verwendet werden:

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>


SELECT (COUNT(*) AS ?count) WHERE { # Count zählt die Einträge
  ?person wdt:P3 wd:Q241.  # Person ist ein(e) (P3) reale Person (Q241)
  SERVICE wikibase:label {     bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".   
  }
}

Klicke hier: SPARQL-Abfrage testen