Rahmenbedingungen der Inszenierungen

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Welche Inszenierungen hatte die meisten/geringsten Aufführungen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?anzahl WHERE {
  ?inszenierung wdt:P16 ?anzahl.  #Inszenierung hat eine Aufführungsanzahl [P16]
  SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
  }
}
ORDER BY DESC(?anzahl)            #Sortiert die Ergebnisse absteigend nach Aufführungsanzahl (DESC für meisten Aufführungen, ASC für gerinsgte Aufführungen)
LIMIT 1                           #Nur die Inszenierung mit den meisten/geringsten Aufführungen wird angezeigt

In Zeile 10 für die meisten Aufführungen „DESC” dort stehen lassen und für die geringste Aufführungsanzahl an dieser Stelle „ASC” einfügen.

Wie lange ging die längste/kürzeste Inszenierung?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?dauer WHERE {
    ?inszenierung wdt:P22 ?dauer.   #Inszenierung hat eine Dauer [P22]
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
    }
}
ORDER BY DESC(?dauer)             #Sortiert die Ergebnisse absteigend nach Länge der Dauer (DESC für Längste, ASC für Kürzeste)
LIMIT 1                           #Nur die länsgte/kürzeste Inszenierung wird angezeigt

In Zeile 10 für die längste Aufführungdauer „DESC” dort stehen lassen und für die kürzeste Aufführungsdauer an dieser Stelle „ASC” einfügen.

Wie lange dauerte die durchschnittliche Aufführung der hier gelisteten Inszenierungen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT (AVG(?dauer) AS ?durchschnittlicheDauer) WHERE { #AVG(?dauer) = Durchschnitt der Dauer gespeichert als ?durchschnittlicheDauer
    ?inszenierung wdt:P22 ?dauer.                       #Inszenierung hat eine Dauer [P22]
}

Welche Inszenierung hatte eine/keine Pause?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?pause WHERE {
    ?inszenierung wdt:P34 ?pause.      #Inszenierung hat eine Anzahl an Pausen
    FILTER (?pause = 0)                #Filtertt Inszenierungen mit 0 Pausen (1 für eine Pause etc.)

    SERVICE wikibase:label {           #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
    }
}

In Zeile 6 bei FILTER (?pause = 0) die Ziffer auf 0 stehen lassen für null Pausen, 1 für eine Pause, 2 für zwei Pausen etc.