Kostüme

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Beschreibung aller Kostüme aller Rollen

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?inszenierungLabel ?rolleLabel ?kostümLabel ?beschreibung WHERE {
   ?rolle wdt:P55 ?kostüm.            #Rolle hat ein Kostüm 
   ?kostüm wdt:P54 ?beschreibung.     #Kostüm hat eine Beschreibung
  
   ?kostüm p:P81 ?statement.          #Kostüm hat ein Statement
   ?statement ps:P81 ?rolle.          #Kostüm gehört zur Rolle
   ?statement pq:P32 ?inszenierung.   #Qualifikator in Inszenierung
  
  SERVICE wikibase:label {            #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

ORDER BY ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen

Aus welchen Teilen setzen sich die einzelnen Kostüme zusammen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?inszenierungLabel ?rolleLabel ?bestandteilLabel ?farbeLabel WHERE {
   ?rolle wdt:P55 ?kostüm.                #Rolle hat ein Kostüm 
  
   ?kostüm p:P50 ?statement.              #Kostüm hat ein Statement
   ?statement ps:P50 ?bestandteil.        #Kostüm besteht aus Bestandteil
   ?statement pq:P49 ?farbe.              #Bestandteil hat eine Farbe im Qualifikator angegeben
  
   ?kostüm p:P81 ?statementzwei.          #Kostüm hat ein Statement
   ?statementzwei ps:P81 ?rolle.          #Kostüm gehört zur Rolle
   ?statementzwei pq:P32 ?inszenierung.   #Qualifikator in Inszenierung
  
  SERVICE wikibase:label {            #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

ORDER BY ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen

Beschreibungen aller Kostüme der Rollen, die auf einer bestimmten lit. Figur basieren

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?inszenierungLabel ?kostümLabel ?beschreibung WHERE {
   wd:Q27 wdt:P88 ?rolle.             #Figur Angeklagter [Q27] ist Grundlage der Rolle [P88] Angeklagte:r 
   ?rolle wdt:P55 ?kostüm.            #Rolle Angeklagte:r hat ein Kostüm [P55]
   ?kostüm wdt:P54 ?beschreibung.     #Kostüm hat eine Beschreibung [P54]
  
   ?kostüm p:P81 ?statement.          #Kostüm hat ein Statement
   ?statement ps:P81 ?rolle.          #Kostüm gehört zur Rolle
   ?statement pq:P32 ?inszenierung.   #Qualifikator in Inszenierung

  SERVICE wikibase:label {            #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

ORDER BY ?inszenierungLabel

In Zeile 5: wd:Q27 für die Rollen, die auf der Figur des Angeklagten basieren. Um die Kostüme anderer Rollen auszugeben, muss die Figur der literarischen Grundlage, auf der sie basiert, geändert werden:

• wd:Q27 für Angeklagter
• wd:Q30 für Protokollführerin
• wd:Q31 für Lauterbach
• wd:Q35 für Meiser
• wd:Q38 für Verteidiger
• wd:Q42 für Staatsanwältin
• wd:Q45 für Vorsitzender
• wd:Q47 für Wachtmeister

Klicke hier: SPARQL-Abfrage testen

Gibt es Inszenierungen, in denen die Rolle des Angeklagten keine Uniform trägt? Wenn ja, welche?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>

SELECT ?inszenierung ?inszenierungLabel ?symbolik ?symbolikLabel WHERE {
  wd:Q27 wdt:P88 ?rolle.                 #Figur Angeklagter [Q27] ist Grundlage der Rolle [P88] Angeklagte:r 

  ?rolle p:P55 ?statement.                #Statement bilden für die Abfrage des Qualifikators. Rolle hat ein statement
  ?statement ps:P55 ?kostüm.              #statement hat ein Kostüm
  ?statement pq:P32 ?inszenierung.        #in Inszenierung
  
  ?kostüm wdt:P56 ?symbolik.             #Kostüm hat eine kontextelle Symbolik [P56]
  FILTER (?symbolik != wd:Q111)          #Filter der Kostüme, die keine Uniform [Q111] sind
  
  SERVICE wikibase:label {               #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen