Abstimmung

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Welches ist die am häufigsten gewählte Abstimmungsart in den hier gelisteten Inszenierungen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?abstimmungsart ?abstimmungsartLabel (COUNT(?interaktionselement) AS ?vorkommen) WHERE {
  ?inszenierung wdt:P83 ?interaktionselement.       #Inszenierung hat ein Interaktionselement [P83]
  ?interaktionselement wdt:P84 ?abstimmungsart.     #Interaktionselement hat eine Abstimmungsart [P84]
  
  SERVICE wikibase:label {                          #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}
GROUP BY ?inszenierung ?inszenierungLabel ?abstimmungsart ?abstimmungsartLabel
HAVING (COUNT(?interaktionselement))                #zeigt die Ergebnisse des COUNT-Befehls aus der SELECT-Formel

Klicke hier: SPARQL-Abfrage testen

Welchen Grad der Sichtbarkeit hatten die Abstimmungen in den jeweiligen Inszenierungen? und welche Abstimmungsart wurde gewählt?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?abstimmungsart ?abstimmungsartLabel ?sichtbarkeit ?sichtbarkeitLabel WHERE {
    ?inszenierung wdt:P83 ?interaktionselement.     #Inszenierung hat ein Interaktionselement [P83]
    ?interaktionselement wdt:P85 ?sichtbarkeit.     #Interaktionselement hat einen Grad der Sichtbarkeit [P85]
    ?interaktionselement wdt:P84 ?abstimmungsart    #Interkationselement hat eine Abstimmungsart [P84]
                         
    SERVICE wikibase:label {                        #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierungen hatten eine nicht sichtbare Abstimmung?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel WHERE {
    ?inszenierung wdt:P83 ?interaktionselement.     #Inszenierung hat ein Interaktionselement [P83]
    ?interaktionselement wdt:P85 wd:Q235.           #Interaktionselement hat Grad der Sichtbarkeit [P85] nicht sichtbar [Q235] (für sichtbar [Q234], für teilweise sichtbar [Q236])
    
  SERVICE wikibase:label {                        #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

In Zeile 6: für eine nicht sichtbare Abstimmung: wd:Q235, für eine sichtbare Abstimmung: wd:Q234 und für eine teilweise sichtbare Abstimmung: wd:Q236.

Klicke hier: SPARQL-Abfrage testen

Liste der Inszenierungen und ihrer Abstimmungsarten und Abstimmungsergebnisse

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>
PREFIX p: <https://mtm.uni-trier.de/prop/>
PREFIX ps: <https://mtm.uni-trier.de/prop/statement/>
PREFIX pq: <https://mtm.uni-trier.de/prop/qualifier/>


SELECT DISTINCT ?inszenierung ?inszenierungLabel ?spielortLabel ?abstimmungsartLabel ?anzahl ?spruchLabel WHERE {
  ?inszenierung wdt:P83 ?interaktionselement.      #Inszenierung hat ein Interaktionselement [P83]
  ?inszenierung wdt:P8 ?spielort.
  ?interaktionselement wdt:P84 ?abstimmungsart.    #Interkationselement hat eine Abstimmungsart [P84]
  
  ?interaktionselement p:P93 ?statement.           #Interaktionselement (der Inszenierung von oben) hat ein Abstimmungsergebnis [P93]
  ?statement ps:P93 ?spruch.                       #Abstimmungsergebnis hat ein Frei- oder Schuldspruch [P93]
  ?statement pq:P57 ?anzahl.                       #Abstimmungsergebnis hat einen Qualifier mit der Anzahl an Vorkomnissen [P57]
  
  
  SERVICE wikibase:label {                         #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }     
}

ORDER BY ?spielort

Klicke hier: SPARQL-Abfrage testen