Rahmenbedingungen der Inszenierungen

zurück zur Übersicht der SPARQL-Abfragethemen: zurück

Welche Inszenierungen hatte die meisten/geringsten Aufführungen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?anzahl WHERE {
  ?inszenierung wdt:P3 wd:Q309.   #Inszenierung ist eine Inszenierung [Q309].
  ?inszenierung wdt:P16 ?anzahl.  #Inszenierung hat eine Aufführungsanzahl [P16]
  SERVICE wikibase:label {        #Fügt lesbare Labels hinzu
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}
ORDER BY DESC(?anzahl)            #Sortiert die Ergebnisse absteigend nach Aufführungsanzahl (DESC für meisten Aufführungen, ASC für geringste Aufführungen)
LIMIT 1                           #Nur die Inszenierung mit den meisten/geringsten Aufführungen wird angezeigt

In Zeile 10 für die meisten Aufführungen „DESC” dort stehen lassen und für die geringste Aufführungsanzahl an dieser Stelle „ASC” einfügen.

In Zeile 11: Um sich alle Inszenierungen inkl. ihrer Aufführungsanzahlen ausgeben zu lassen, „LIMIT 1” löschen.

Klicke hier: SPARQL-Abfrage testen

Wie lange dauerte die längste/kürzeste Inszenierung?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?dauer WHERE {
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P22 ?dauer.   #Inszenierung hat eine Dauer [P22]
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
    }
}
ORDER BY DESC(?dauer)             #Sortiert die Ergebnisse absteigend nach Länge der Dauer (DESC für Längste, ASC für Kürzeste)
LIMIT 1                           #Nur die länsgte/kürzeste Inszenierung wird angezeigt

In Zeile 10 für die längste Aufführungsdauer „DESC” dort stehen lassen und für die kürzeste Aufführungsdauer an dieser Stelle „ASC” einfügen.

In Zeile 11: Um sich alle Inszenierungen inkl. ihrer Aufführungsdauer ausgeben zu lassen, „LIMIT 1” löschen.

Klicke hier: SPARQL-Abfrage testen

Wie lange dauerte die durchschnittliche Aufführung der hier gelisteten Inszenierungen?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT (AVG(?dauer) AS ?durchschnittlicheDauer) WHERE { #AVG(?dauer) = Durchschnitt der Dauer gespeichert als ?durchschnittlicheDauer
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P22 ?dauer.                       #Inszenierung hat eine Dauer [P22]
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
    }
}

Nach Zeile 5 kann „?inszenierung wdt:P4 wd:Q3. ” eingefügt werden, sollte sich die Abfrage nur auf Inszenierungen beziehen, die auf der literarischen Vorlage „Terror” basieren (sobald weitere Inszenierungen auf dieser Wikibase-Instanz modelliert sind, die sich auch auf andere Werke beziehen)

Klicke hier: SPARQL-Abfrage testen

Welche Inszenierung hatte eine/keine Pause?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?inszenierung ?inszenierungLabel ?pause WHERE {
    ?inszenierung wdt:P3 wd:Q309.
    ?inszenierung wdt:P34 ?pause.      #Inszenierung hat eine Anzahl an Pausen
    FILTER (?pause = 0)                #Filtertt Inszenierungen mit 0 Pausen (1 für eine Pause etc.)

    SERVICE wikibase:label {           #Fügt lesbare Labels hinzu
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".
    }
}

In Zeile 6 bei FILTER (?pause = 0) die Ziffer auf 0 stehen lassen für null Pausen, 1 für eine Pause, 2 für zwei Pausen etc.

Klicke hier: SPARQL-Abfrage testen

Visualisierung der Aufführungsdaten als Scatter Chart und Timeline

Scatter Chart:

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

#defaultView:ScatterChart
SELECT ?datum ?inszenierungLabel ?ortLabel WHERE {
?inszenierung wdt:P37 ?datum.
?inszenierung wdt:P8 ?ort.
  
SERVICE wikibase:label {                         #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
    }
}

ORDER BY ?datum

Klicke hier: SPARQL-Abfrage testen

Timeline:

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

#defaultView:Timeline
SELECT ?datum ?inszenierungLabel ?ortLabel WHERE {
?inszenierung wdt:P37 ?datum.
?inszenierung wdt:P8 ?ort.
  
SERVICE wikibase:label {                         #Sorgt für lesbare Labels
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
    }
}

ORDER BY ?datum

Klicke hier: SPARQL-Abfrage testen