Personen

zurück zur Übersicht der Abfragen: zurück

Bilder der gelisteten Personen

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX mmd: <https://mtm.uni-trier.de/entity/> 
PREFIX mmdt: <https://mtm.uni-trier.de/prop/direct/>
#defaultView:ImageGrid
SELECT ?personLabel ?bild WHERE {
    ?person mmdt:P3 mmd:Q241. #Person ist eine reale Person
    ?person mmdt:P2 ?WikiDataEntity. #Person hat ein exact match mit einem Wikidata-Item
  
    SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P18 ?bild.  # Wikidata-Item hat über P18 ein Bild
    }
  
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

Klicke hier: SPARQL-Abfrage testen

Karte der Geburtsorte aller realen Personen auf dieser Wikibase-Instanz

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX mmd: <https://mtm.uni-trier.de/entity/> 
PREFIX mmdt: <https://mtm.uni-trier.de/prop/direct/>
#defaultView:Map
SELECT ?personLabel ?geburtsortLabel ?koordinaten WHERE {
    ?person mmdt:P3 mmd:Q241. #Person ist eine reale Person
    ?person mmdt:P2 ?WikiDataEntity. #Person hat ein exact match mit einem Wikidata-Item
  
    SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P19 ?geburtsort.  # Wikidata-Item hat über P19 einen Geburtsort
    ?geburtsort wdt:P625 ?koordinaten.    # P625 = Koordinaten in Wikidata
    }
  
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

Klicke hier: SPARQL-Abfrage testen

Liste aller Personen mit ihrem Gender und ihrer Funktion innerhalb der Inszenierung

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT  ?inszenierungLabel ?personLabel ?vornameLabel ?nachnameLabel ?genderLabel ?funktionLabel WHERE {
  ?person wdt:P3 wd:Q241. #Person ist eine reale Person
  OPTIONAL { #Falls in einem Personen-Item diese Informationen fehlen
  ?person wdt:P17 ?gender. #Person hat Gender
  ?person wdt:P27 ?vorname. #Person hat Vorname
  ?person wdt:P28 ?nachname. } #Person hat Nachname
  ?inszenierung ?funktion ?person. #Inszenierung ist über eine Funktion mit der Person verknüpft.
  ?inszenierung wdt:P3 wd:Q309. #Inszenierung ist eine Inszenierung
  
SERVICE wikibase:label {                          
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de". #Fügt lesbare Labels hinzu
  }
}

ORDER BY ?inszenierung

Klicke hier: SPARQL-Abfrage testen

Gibt es eine Regieperson, die mehrere Inszenierungen betreut hat? Wenn ja, welche waren es?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?regie ?regieLabel ?inszenierung ?inszenierungLabel WHERE {
  
  {
    SELECT ?regie (COUNT(?inszenierung) AS ?anzahlInszenierungen) WHERE { #Query für Anzahl der Inszenierungen
      ?inszenierung wdt:P15 ?regie. #Inszenierung hat Regisseur:in 
    }
    GROUP BY ?regie ?regieLabel       #Es wird nach Regisseur:innen und ihrem Label gruppiert
    HAVING (COUNT(?inszenierung) > 1) #Sollte es mehr als eine Inszenierung geben ->
  }
  
  ?inszenierung wdt:P15 ?regie.     #Hauptquery, um Inszenieurng der Regieperson im Ergebnis mit ausgeben zu können

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}
ORDER BY ?regieLabel ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen

Gibt es eine:n Darsteller:in, der oder die bei mehreren Inszenierungen mitspielte? Wenn ja, welche waren es?

PREFIX wdt: <https://mtm.uni-trier.de/prop/direct/>
PREFIX wd: <https://mtm.uni-trier.de/entity/>

SELECT ?darstellerIn ?darstellerInLabel ?inszenierung ?inszenierungLabel WHERE {
{
SELECT ?darstellerIn ?darstellerInLabel (COUNT(?inszenierung) AS ?count) WHERE { #Query von Frage davor als Subquery für Anzahl der Inszenierungen
  ?inszenierung wdt:P14 ?darstellerIn.                                           #Inszenierung hat ein:e Schauspieler:in 
}
GROUP BY ?darstellerIn ?darstellerInLabel
HAVING (COUNT(?inszenierung) > 1)
}
?inszenierung wdt:P14 ?darstellerIn.                                              #Hauptquery, um Inszenieurng der Schauspieler:in im Ergebnis mit ausgeben zu können

  SERVICE wikibase:label {                                                        #Fügt lesbare Labels hinzu
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE], de".
  }
}

ORDER BY ?darstellerInLabel ?inszenierungLabel

Klicke hier: SPARQL-Abfrage testen